#! /bin/awk -f
#
#------------------------------------------------------------------------------
# This awk script reads in an IEHLIST LISTVTOC listing and generates an IDCAMS
# jobstream to define the catalog entries for the datasets.
#    !!! set volume/unit values in BEGIN before executing !!!
#
# Syntax: gawk -f catalog.awk [IEHLIST output] > [generated jobstream]
#------------------------------------------------------------------------------
#
#------------------------------------------------------------------------------
# set array of unit[volume] to unit type and generate JCL for IEHPROGM
#------------------------------------------------------------------------------
BEGIN {
  unittype["SMP001"] = "3350";
  unittype["WORK02"] = "3350";
  print "//IDCAMS   JOB CLASS=A,MSGLEVEL=(1,1)"
  print "//* GENERATED BY CATALOG.AWK"
  print "//IDCAMS   EXEC PGM=IDCAMS,REGION=1024K"
  print "//SYSPRINT DD  SYSOUT=A"
  print "//SYSIN    DD  *"
  } # BEGIN
#
#------------------------------------------------------------------------------
# Generate IDCAMS command for each dataset
#------------------------------------------------------------------------------
/-DATA SET NAME-/ {
  getline;              # read next statement from input stream
  print " DEFINE NONVSAM ( NAME ( " $1 " ) -";
  print "                  VOLUMES ( " $3 " ) -";
  print "                  DEVICETYPES ( " unittype[$3] " ) )"
  } # /-DATA SET NAME-/
#
#------------------------------------------------------------------------------
# terminate generated jobstream
#------------------------------------------------------------------------------
END {
  print "/*"
  print "//"
  } # END